Can I create Windows executables using Kylix?

No you can't. If you want to build Windows applications you'll need to buy Delphi Open Edition.

How Can I Remove The Kylix Open Edition Banner?

Kylix Open Edition GPL applications like to adevertise the product used to create them. GUI (X windows) applications display a stay-on-top window for three seconds. To remove the nag screen, without clicking on the nag screen itself, just add the -ns switch as a run parameter. For those of you who are new to Kylix, simply go to the Run menu and select the "Parameters ..." entry. Then inside the Parameters edit box add "-ns". To remove the nag message from console applications, simply remove the {$APPTYPE CONSOLE} message from the project source file.

How can call another program using Kylix?

To call another program from your application you need to use the system function. It calls another process, keeping it until it ends.

procedure TForm1.Button1Click(Sender:TObject);
var
    App : Integer;
begin
    App := Libc.System('kcalc');
    if App = -1 then
    ShowMessage('Error executing your program');
end;

Determining Kylix application and library dependancies.

When distributing your Kylix applications, you may need to determine the libraries that your application replies on. There is a tool within Linux called ldd. This tool lists the dependancies for a given application. We can use this to determine the library requirements/dependancies.
The following is the output for the console hello world application:

[bear@splhcb hello]# ldd hello
/lib/libNoVersion.so.1 => /lib/libNoVersion.so.1 (0x40018000)
libpthread.so.0 => /lib/i686/libpthread.so.0 (0x4002f000)
libdl.so.2 => /lib/lib/libdl.so.2 (0x40044000)
libc.so.6 => /lib/i686/libc.so.6 (0x40048000)
/lib/ld-linux.so.2 => /lib/ld-linux.so.2 (0x40000000)

Determining user home directory.

Tip from http://www.kylixforum.de/forum (German language)

uses SysUtils;
var
  HomeDir: string;
begin
  HomeDir := GetEnviromentVariable('HOME');
  //HomeDir - '/home/ace'
end;

Fast string replace (Quick alternative for SysUtils function StringReplace).

Tip from http://www.kylixforum.de/forum (German language)

String: MakeString('Text', 50000);
Replace: 'Text' to 'Hallo';
Computer: Pentium 4 2GHz, WindowsXP;

FastStringReplace: 16 ms
StringReplace: 82047 ms

function StrEqualText(Text: PChar; SearchText: PChar; MaxLen: Integer;
  IgnoreCase: Boolean): Boolean;
var
  i: Integer;
begin
  if IgnoreCase then
    Result := StrLIComp(Text, SearchText, MaxLen) = 0
  else
  begin
    Result := False;
    for i := 0 to MaxLen - 1 do
      if (Text[i] = #0) or {(SearchText[i] = #0) or}
         (Text[i] <> SearchText[i]) then Exit;
    Result := True;
  end;
end;



function FastStringReplace(const Text, SearchText, ReplaceText: string;
  ReplaceAll, IgnoreCase: Boolean): string;
var
  LenSearchText, LenReplaceText, LenText: Integer;
  Index, Len, StartIndex: Integer;
begin
  LenSearchText := Length(SearchText);
  LenReplaceText := Length(ReplaceText);
  LenText := Length(Text);
  if LenSearchText = 0 then
  begin
    Result := Text;
    Exit;
  end;

 // Speicher für den schlimmsten Fall reservieren.
  if ReplaceAll then
  begin
    if LenReplaceText - LenSearchText > 0 then
      SetLength(Result, LenText +
        (LenReplaceText - LenSearchText) * (LenText div LenSearchText))
    else
      SetLength(Result, LenText);
  end
  else
    SetLength(Result, LenText + (LenReplaceText - LenSearchText));


  Len := 0;
  StartIndex := 1;
  for Index := 1 to LenText do
  begin
    if StrEqualText(PChar(Pointer(Text)) + Index - 1, Pointer(SearchText),
                   LenSearchText, IgnoreCase) then
    begin
     // davor liegenden Text kopieren
      if Index > StartIndex then
      begin
        Move(Text[StartIndex], Result[Len + 1], Index - StartIndex);
        Inc(Len, Index - StartIndex);
      end;
      StartIndex := Index + LenSearchText;

     // Ersetzungstext einfügen
      if LenReplaceText > 0 then
      begin
        Move(ReplaceText[1], Result[Len + 1], LenReplaceText);
        Inc(Len, LenReplaceText);
      end;

      if not ReplaceAll then Break;
    end;
  end;

 // Rest kopieren
  Index := LenText + 1;
  if Index > StartIndex then
  begin
    Move(Text[StartIndex], Result[Len + 1], Index - StartIndex);
    Inc(Len, Index - StartIndex);
  end;

  SetLength(Result, Len); // String auf die tatsächliche Länge kürzen
end;

Tray Icon in Kylix.

Tip from http://www.kylixforum.de/forum (German language)

Original Text: http://www.efg2.com/Lab/Library/Kylix/MatthiasThoma/KDESystemTray.html

uses
  Xlib, Qt;

procedure TForm1.FormCreate(Sender: TObject);
var
  prop: TAtom;
  data: TAtom;
begin

  Width := 24; // Icons im KDE-SystemTray sollten 24x24 Pixel groß sein,
  Height := 24; // größere werden beschnitten, kann auch im ObjectInspector gesetzt werden

  // Die zwei folgenden Zeilen müssen hier stehen,
  // es nützt nichts, wenn sie im ObjectInspector gesetzt werden
  BorderStyle := fbsNone;
  BorderIcons := [];

  // Mit den nachfolgenden Zeilen wird unser Fenster in den SystemTray eingefügt
  prop := XInternAtom(Application.Display, '_KDE_NET_WM_SYSTEM_TRAY_WINDOW_FOR', 1);
  XChangeProperty(Application.Display, QWidget_winId(self.Handle), prop,
  XA_WINDOW, 32, PropModeReplace, PByte(@data), 1);
end;

Draw rotated text on Canvas.

Tip from http://www.kylixforum.de/forum (German language)

uses Qt;

...

procedure TForm1.RotatedText(Cnv: TCanvas; Wkl: Integer; Pxy: TPoint; Txt: string);
var
  PrPoint: TPoint;
begin
  Cnv.Start;
  // Canvas rotieren.
  QPainter_rotate(Cnv.Handle, Wkl);
  // Device Koordinaten zu Modell-Koordinaten konvertieren.
  QPainter_xFormDev(Cnv.Handle, PPoint(@PrPoint), PPoint(@Pxy));
  // Text ausgeben.
  Cnv.TextOut(PrPoint.X, PrPoint.Y, Txt);
  Cnv.Stop;
end;

Generic detokenizer .

Tip from http://www.codebake.com

The following is a routine that will enabled you to remove a particular charater or string from an expression. This is very useful, for example, to remove the $ from a string to convert to a curreny value.

Function Detokenizer(Const Tokens: array of string; Const Expression: String): String;
Var
  LoopIdx: Integer;
Begin
  Result := Expression;
  For LoopIdx := Low(Tokens) to High(Tokens) do Begin
    While Pos(Tokens[LoopIdx], Result) <> 0 do Begin
      Delete(Result, Pos(Tokens[LoopIdx], Result), Length(Tokens[LoopIdx]));
    End;
  End;
End;

To use this function simply enter in the strings into the Tokens array. E.g.

  ParsedAmountEdt.Text := Detokenizer(['%','$','US','AUD'],AmountEdt.Text);

Therefore, if the function finds either '%', '$', 'US' or 'AUD' in the original string, then the detokenizer will remove these entries.

Setting common properties on multiple controls.

Tip from http://www.codebake.com

There is often a need to set common properties (e.g. visible or enabled properties) of a group of controls. This is often performed when state information has changed for an application.

The procedure below sets the visible state for a series of Controls.

Procedure SetVisibleProp(Const ControlSet: array of TControl; Const NewState: Boolean);
Var
  i: Integer;
Begin
  for i:= Low(ControlSet) to High(ControlSet) do Begin
    TControl(ControlSet[i]).Visible := NewState;
  End;
End;

To use the procedure above:

  SetVisibleProp([NewBtn,OpenBtn,SaveBtn],UserState <> usNotAuthorized);
  

This example can be extended to set any properties of the TControl object.

Defining your own global exception handler.

Tip from http://www.codebake.com

The TApplication class has defined a call back event that allows you to handle exceptions if you choose. Simply assign a method to the TApplication.OnException event. To do this, we need to create a method of type TExceptionEvent.

unit Unit1;

interface

uses
  SysUtils, Types, Classes, Variants, QGraphics, QControls, QForms, QDialogs,
  QStdCtrls;

type
  TMainForm = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Edit1: TEdit;
    procedure FormCreate(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
    Procedure LogException(Const ErrorMsg: String);
    Procedure MyExceptionHandler(Sender: TObject; E: Exception);
end;

var
  MainForm: TMainForm;

implementation

procedure TMainForm.FormCreate(Sender: TObject);
begin

{Assign my defined exception handler to the Application.OnException handler}

  Application.OnException := MyExceptionHandler;
end;

Procedure TMainForm.MyExceptionHandler(Sender: TObject; E: Exception);
Begin
{log exception entry to a file}
  LogException(E.Message);
  Application.ShowException(E);
End;

end.

There is no need to override the TApplication.OnException just to call Application.ShowException.

As Stated in the Delphi help file:
"Calling ShowException is rarely necessary in a Delphi application, since the default VCL exception handler will call ShowException automatically."

You will generally override the OnException handler to perform additional or different functionality that is already performed by the default exception handler. For example, the above example logs all errors via a LogException(E.Message) call. It then calls the Application.ShowException(E).

Other reasons to override the default exception handler include:

   Define a new exception display form, rather than the default exception message dialog.
   Application/System/Exception Debugging
   Resetting application or state information